CFTABLE |
Description Builds a table in a ColdFusion page. This tag renders data as preformatted text, or, with the HTMLTable attribute, in an HTML table. If you don't want to write HTML table tag code, or if your data can be presented as preformatted text, use this tag.

Preformatted text (defined in HTML with the <pre> and </pre> tags) displays text in a fixed-width font. It displays white space and line breaks exactly as they are written within the pre tags. For more information, see an HTML reference guide.

To define table column and row characteristics, use the cfcol tag within this tag.

Category Data output tags
Syntax
    <cftable
       query = "query_name"
       maxRows = "maxrows_table"
       colSpacing = "number_of_spaces"
       headerLines = "number_of_lines"
       HTMLTable
       border
       colHeaders
       startRow = "row_number">
       ...
    </cftable>
See also cfcol, cfcontent, cflog, cfoutput, cfprocessingdirective, cftable; "Retrieving data" in Chapter 20, "Accessing and Retrieving Data," in ColdFusion MX Developer's Guide
Usage This tag aligns table data, sets column widths, and defines column heads. At least one cfcol tag is required within this tag. You must put cfcol and cftable tags adjacent in a page. The only tag that you can nest within this tag is the cfcol tag. You cannot nest cftable tags.

To display the cfcol header text, you must specify the cfcol header and the cftable colHeader attribute. If you specify either attribute without the other, the header does not display and no error is thrown.

Example
    <!--- This example shows the use of cfcol and cftable to align information
    returned from a query. --->
    <!--- This query selects employee information from cfdocexamples
    datasource. --->
    <cfquery name = "GetEmployees" dataSource = "cfdocexamples">
       SELECT Emp_ID, FirstName, LastName, EMail, Phone, Department
       FROM Employees
    </cfquery>

    <html>
    <body>
    <h3>cftable Example</h3>

    <!--- Note use of HTMLTable attribute to display cftable as an HTML table,
    rather than as PRE formatted information. --->
    <cftable query = "GetEmployees"
       startRow = "1" colSpacing = "3" HTMLTable>
    <!--- Each cfcol tag sets width of a column in table, and specifies header
    information and text/CFML with which to fill cell. --->
       <cfcol header = "<b>ID</b>"
          align = "Left"
          width = 2
          text  = "#Emp_ID#">

       <cfcol header = "<b>Name/Email</b>"
          align = "Left"
          width = 15
          text  = "<a href = 'mailto:#Email#'>#FirstName# #LastName#</A>">

       <cfcol header = "<b>Phone Number</b>"
          align = "Center"
          width = 15
          text  = "#Phone#">
    </cftable>
    </body>
    </html>

QUERY |
| Required
Name of cfquery from which to draw data.

MAXROWS |
| Optional
Maximum number of rows to display in the table.

COLSPACING |
| Optional
Default value: "2" Number of spaces between columns.

HEADERLINES |
| Optional
Default value: "2" Number of lines to use for table header (the default leaves one line between header and first row of table).

HTMLTABLE |
| Optional
Renders data in an HTML 3.0 table. If you use this attribute (regardless of its value), ColdFusion renders data in an HTML table.

BORDER |
| Optional
Displays border around table. If you use this attribute (regardless of its value), ColdFusion displays a border around the table. Use this only if you use the HTMLTable attribute.

COLHEADERS |
| Optional
Displays column heads. If you use this attribute, you must also use the cfcol tag header attribute to define them. If you use this attribute (regardless of its value), ColdFusion displays column heads.

STARTROW |
| Optional
Default value: "1" The query result row to put in the first table row.