generate-id() Function |
Generates a unique ID (an XML name) for a given node. If no node-set is given, generate-id() generates an ID for the context node.
Inputs
An optional node-set. If no node-set is given, this function generates an ID for the context node. If the node-set is empty, generate-id() returns an empty string.
Output
A unique ID, or an empty string if an empty node-set is given. Several things about the generate-id() function are important to know:

  For a given transformation, every time you invoke generate-id() against a given node, the XSLT processor must return the same ID. The ID can't change while you're doing a transformation. If you ask the XSLT processor to transform your document with this stylesheet tomorrow, there's no guarantee that generate-id() will generate the same ID the second time around. All of tomorrow's calls to generate-id() will generate the same ID, but that ID might not be the one generated today.
  The generate-id() function is not required to check if its generated ID duplicates an ID that's already in the document. In other words, if an element in your document has an attribute of type ID with the value sdk3829a, there's a remote possibility that an ID returned by generate-id() would have the value sdk3829a. It's not likely, but it could happen.
  If you invoke generate-id() against two different nodes, the two generated IDs must be different.
  Given a node-set, generate-id() returns an ID for the node in the node-set that occurs first in document order.
  If the node-set you pass to the function is empty (you invoke generate-id(fleeber), but there are no <fleeber> elements in the current context), generate-id() returns an empty string.

Defined in
XSLT section 12.4, Miscellaneous Additional Functions.
Example
Here's a simple stylesheet that uses the document('') function to access all of its own <xsl:text> nodes. It then uses generate-id() to generate a unique ID for each of those nodes, then calls generate-id() again to illustrate that the function generates the same ID for a given node. Here's the stylesheet:
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:output method="text"/>

      <xsl:variable name="newline">
    <xsl:text>
    </xsl:text>
      </xsl:variable>

      <xsl:template match="/">
        <xsl:value-of select="$newline"/>
        <xsl:text>A test of the generate-id() function:</xsl:text>

        <xsl:value-of select="$newline"/>
        <xsl:value-of select="$newline"/>
        <xsl:for-each select="document('')//xsl:text">
          <xsl:text>Node name: </xsl:text>
          <xsl:value-of select="name()"/>
          <xsl:text> - generated id: </xsl:text>
          <xsl:value-of select="generate-id()"/>
          <xsl:value-of select="$newline"/>
        </xsl:for-each>
        <xsl:value-of select="$newline"/>
        <xsl:value-of select="$newline"/>
        <xsl:text>Now we'll try it again...</xsl:text>
        <xsl:value-of select="$newline"/>
        <xsl:value-of select="$newline"/>
        <xsl:for-each select="document('')//xsl:text">
          <xsl:text>Node name: </xsl:text>
          <xsl:value-of select="name()"/>
          <xsl:text> - generated id: </xsl:text>
          <xsl:value-of select="generate-id()"/>
          <xsl:value-of select="$newline"/>
        </xsl:for-each>
      </xsl:template>

    </xsl:stylesheet>
Our stylesheet generates these results:
    A test of the generate-id() function:

    Node name: xsl:text - generated id: NC
    Node name: xsl:text - generated id: N16
    Node name: xsl:text - generated id: N22
    Node name: xsl:text - generated id: N28
    Node name: xsl:text - generated id: N38
    Node name: xsl:text - generated id: N44
    Node name: xsl:text - generated id: N4A

    Now we'll try it again...

    Node name: xsl:text - generated id: NC
    Node name: xsl:text - generated id: N16
    Node name: xsl:text - generated id: N22
    Node name: xsl:text - generated id: N28
    Node name: xsl:text - generated id: N38
    Node name: xsl:text - generated id: N44
    Node name: xsl:text - generated id: N4A
The IDs generated each time are the same.